Excel fájlok formázása ciklussal, Access VBA kóddal

Excel fájlok formázása ciklussal, Access VBA kóddal
2017-04-30T10:53:38+02:00
2017-04-30T15:25:53+02:00
2022-12-04T13:05:39+01:00
Tcsaba73
Üdvözlet Mindenkinek!

Elakadtam, nem tudom, hogy mi lehet a konkrét probléma.
Excel fájlokat exportálok Access adatbázisból Access VBA kóddal. Erre egy ciklus van szervezve.
Ez műkszik is rendesen.
Szeretném megformázni ciklussal az exportált Excel fájlokat.
Az Excel fájlokat, Access VBA kóddal egyeséve megnyitom és az alábbi kóddal formázom:

Access 2003 és Excel 2003

'================================================================
    Dim xlApp As Excel.Application
    Dim xlwkb As Object
    Dim Tart As String

    Set xlApp = CreateObject("Excel.Application")
    xlApp.Workbooks.Open UtvonalGlb ' A fájl elérési útvonala.  
    Set xlwkb = xlApp.Application.ActiveWorkbook

    xlApp.Application.Visible = True    

    Tart = "A1:G1"
    
    ' Ablaktábla rögzítése...
    xlwkb.Worksheets(1).Cells(2, 1).Activate
    xlApp.ActiveWindow.FreezePanes = True
        
    ' Fejléc beállítása...
    With xlwkb.Worksheets(1).Range(Tart)
        ' Excel felső sorok színezése...
        .Font.Color = 16777215 ' Fehér betűk
        .Font.Bold = True ' Félkövér
        .Interior.Color = 16711680 ' Kék háttér
    End With
       
    ' Oldalbeállítás...
    With xlwkb.Worksheets(1).PageSetup
        ' Oldal tájolása...
        .Orientation = xlLandscape ' Fekvő
        ' Margók...
        .HeaderMargin = 22.677
        .FooterMargin = 22.677
        .TopMargin = 34.015
        .BottomMargin = 34.015
        .LeftMargin = 28.346
        .RightMargin = 28.346
        ' Oldal nagyítása...
        .Zoom = False
        .FitToPagesTall = 400
        .FitToPagesWide = 1
        ' Lapon, Fent ismétlődő sorok...
        .PrintTitleRows = ActiveSheet.Rows(1).Address
        ' Egyéni fej- és lábléc...
        .CenterHeader = "&12- &P -"
        .RightHeader = "&12Összesen: &N"
        .CenterFooter = "&12Dt.: &D &T"
    End With
    
    xlApp.Application.Visible = True
    
    ' Excel mentése...
    xlApp.ActiveWorkbook.Save
    
    Set xlwkb = Nothing
    Set xlApp = Nothing
'================================================================

Az alábbi hibajelzés, a második futtatásnál jelentkezik:
"Object varable or With block varable not set"
(Az Access nem akad ki.)
A hibajelzés után újra kell indítani az Accesst, ahhoz, hogy megcsinálja elsőre jól.
Az első futtatás tökéletesen lefut. Az összes többi futtatás hibajelzésre fut.
Attól függetlenül is hibára fut, ha ez első Excel fájlt már bezártam.
(A fájlok elérési útja folyamatosan változik.)

Már nagyon sokat gugliztam a problémára, de megoldást egyenlőre nem találtam.

Valakinek ötlet, megoldás?
Mutasd a teljes hozzászólást!
Megoldottam.
A hibát a fent ismétlődő sorok beállítása okozta.

Helyesen:
        ' Lapon, Fent ismétlődő sorok...
        .PageSetup.PrintTitleRows = "$1:$1"
Mutasd a teljes hozzászólást!

Tetszett amit olvastál? Szeretnél a jövőben is értesülni a hasonló érdekességekről?
abcd